Sequences

To what does the sequence a[n] = 1 + (-1)^n / n^2 converge? The answer leaps out of a graph if we plot the points
 ( -1/n, a[n]  ).

a[n_] = 1.+ (-1)^n / (n^2);
spoints = Table[ {-1/n,a[n]}, {n,1,128} ];
plot1 = ListPlot[  spoints
           ,PlotStyle->PointSize[0.02]
           ,PlotRange->{{-1.1,.01},{-.1,2}}
           ,Ticks->{{ 0.5}, {0,1,2} }];

Looks like the points cluster near ( 0, 1).  The limit of the sequence is the  y-coordinate of the limit point, which is  1.  To illustrate the epsilon-tolerances, we zoom in on the graph, and add two lines for  1 + epsilon and  1 - epsilon.  In this case, epsilon is  .004.The "tail" lies between the lines.

a[n_] = 1.+ (-1)^n / (n^2);
spoints = Table[ {-1/n,a[n]}, {n,1,512} ];
plot1 = ListPlot[  spoints
           ,PlotStyle->PointSize[0.02]
           ,PlotRange->{{-.15,.01},{.98,1.02}}
           ,Ticks->{{ 0.1}, Automatic} ];
plot2 =Plot[ {1.004,.996},{x,-.15,0} ];
Show[ plot1, plot2 ];

Another more "advanced" concept is the idea of a limit superior.  Some sequences don't settle down to a limit but instead careen about wildly. The following graph illustrates a sequence that has a limit superior of  2.5.  That is, no matter which tail we look at, we can always find a value that is very close to  2.5, but we cannot do it for any larger y-value (e.g., not for 2.6).

c[n_] = 3/2 + n / (n +50) Sin[3n];
spoints = Table[ { -1/n, c[n] }, {n,1,4096} ];
plot1 = ListPlot[  spoints
           ,PlotStyle->PointSize[0.01]
           ,AspectRatio->1/GoldenRatio
           ,PlotRange->{{-.02,.0001},{0,3}}
           ,Ticks->{{ }, {.5,1,1.5,2,2.5}}] ;

Can you guess the technical meaning of a limit inferior?

The next sequence may be more challenging.  What is the liim sup and lim inf of this sequence?

c[n_] = 2/5 + (n+50) / (n) Sin[3n];
spoints = Table[ { -1/n, c[n] }, {n,1,4096} ];
plot1 = ListPlot[  spoints
           ,PlotStyle->PointSize[0.01]
           ,AspectRatio->1/GoldenRatio
           ,PlotRange->{{-.02,.0001},{-1,2}}
           ,Ticks->{{ .01}, Automatic }] ;

The following sequence consists of three different parts, each getting a turn at determining the sequences value. By using the same graphing trick, we can read off the set of subsequential limits.  Like the lim sup and lim inf, a subsequential limit is a limiting value that we can obtain from some convergent subsequence.  The lim inf happens to be the least of the set of subsequential limits.  What do you think the biggest subsequential limit is called?

b1[n_] = 400 (-1)^(n) /n^2;
b2[n_] = .4+ ((n^1.3)/100+2)/(5 (n^1.3)/100 +1) Sin[3 n];
b3[n_] = 1 - 20/n;
spoints = Flatten[ Table[  { {-1/(3n),    b1[n]}, 
                           {-1/(3n +1), b2[n]},
                           {-1/(3n +2), b3[n]} }, 
                         {n,16,2048}], 1
                  ];
ListPlot[  spoints 
           ,PlotStyle->PointSize[0.01]
           ,AspectRatio->1
           ,PlotRange->{{-.019,.001},{-.4,1.1}}
           ,AxesOrigin->{0,0} 
           ,Ticks->{{0.005, 0.01, 0.015}, Automatic}] ;

What is the lim sup and lim inf of this sequence?


Describe carefully the set of subseqential limits.


Use the diagram to explain how you would choose a (sub)sequence that converges to a point in the set of subseqential limits.